asan_ppc64le.s

     1  // Copyright 2022 The Go Authors. All rights reserved.
     2  // Use of this source code is governed by a BSD-style
     3  // license that can be found in the LICENSE file.
     4  
     5  //go:build asan
     6  
     7  #include "go_asm.h"
     8  #include "textflag.h"
     9  
    10  #define RARG0 R3
    11  #define RARG1 R4
    12  #define RARG2 R5
    13  #define RARG3 R6
    14  #define FARG R12
    15  
    16  // Called from instrumented code.
    17  // func runtime·doasanread(addr unsafe.Pointer, sz, sp, pc uintptr)
    18  TEXT	runtime·doasanread(SB),NOSPLIT|NOFRAME,$0-32
    19  	MOVD	addr+0(FP), RARG0
    20  	MOVD	sz+8(FP), RARG1
    21  	MOVD	sp+16(FP), RARG2
    22  	MOVD	pc+24(FP), RARG3
    23  	// void __asan_read_go(void *addr, uintptr_t sz, void *sp, void *pc);
    24  	MOVD	$__asan_read_go(SB), FARG
    25  	BR	asancall<>(SB)
    26  
    27  // func runtime·doasanwrite(addr unsafe.Pointer, sz, sp, pc uintptr)
    28  TEXT	runtime·doasanwrite(SB),NOSPLIT|NOFRAME,$0-32
    29  	MOVD	addr+0(FP), RARG0
    30  	MOVD	sz+8(FP), RARG1
    31  	MOVD	sp+16(FP), RARG2
    32  	MOVD	pc+24(FP), RARG3
    33  	// void __asan_write_go(void *addr, uintptr_t sz, void *sp, void *pc);
    34  	MOVD	$__asan_write_go(SB), FARG
    35  	BR	asancall<>(SB)
    36  
    37  // func runtime·asanunpoison(addr unsafe.Pointer, sz uintptr)
    38  TEXT	runtime·asanunpoison(SB),NOSPLIT|NOFRAME,$0-16
    39  	MOVD	addr+0(FP), RARG0
    40  	MOVD	sz+8(FP), RARG1
    41  	// void __asan_unpoison_go(void *addr, uintptr_t sz);
    42  	MOVD	$__asan_unpoison_go(SB), FARG
    43  	BR	asancall<>(SB)
    44  
    45  // func runtime·asanpoison(addr unsafe.Pointer, sz uintptr)
    46  TEXT	runtime·asanpoison(SB),NOSPLIT|NOFRAME,$0-16
    47  	MOVD	addr+0(FP), RARG0
    48  	MOVD	sz+8(FP), RARG1
    49  	// void __asan_poison_go(void *addr, uintptr_t sz);
    50  	MOVD	$__asan_poison_go(SB), FARG
    51  	BR	asancall<>(SB)
    52  
    53  // func runtime·asanregisterglobals(addr unsafe.Pointer, n uintptr)
    54  TEXT	runtime·asanregisterglobals(SB),NOSPLIT|NOFRAME,$0-16
    55  	MOVD	addr+0(FP), RARG0
    56  	MOVD	n+8(FP), RARG1
    57  	// void __asan_register_globals_go(void *addr, uintptr_t n);
    58  	MOVD	$__asan_register_globals_go(SB), FARG
    59  	BR	asancall<>(SB)
    60  
    61  // func runtime·lsanregisterrootregion(addr unsafe.Pointer, n uintptr)
    62  TEXT	runtime·lsanregisterrootregion(SB),NOSPLIT|NOFRAME,$0-16
    63  	MOVD	addr+0(FP), RARG0
    64  	MOVD	n+8(FP), RARG1
    65  	// void __lsan_register_root_region_go(void *addr, uintptr_t n);
    66  	MOVD	$__lsan_register_root_region_go(SB), FARG
    67  	BR	asancall<>(SB)
    68  
    69  // func runtime·lsanunregisterrootregion(addr unsafe.Pointer, n uintptr)
    70  TEXT	runtime·lsanunregisterrootregion(SB),NOSPLIT|NOFRAME,$0-16
    71  	MOVD	addr+0(FP), RARG0
    72  	MOVD	n+8(FP), RARG1
    73  	// void __lsan_unregister_root_region_go(void *addr, uintptr_t n);
    74  	MOVD	$__lsan_unregister_root_region_go(SB), FARG
    75  	BR	asancall<>(SB)
    76  
    77  // func runtime·lsandoleakcheck()
    78  TEXT	runtime·lsandoleakcheck(SB), NOSPLIT|NOFRAME, $0-0
    79  	// void __lsan_do_leak_check_go(void);
    80  	MOVD	$__lsan_do_leak_check_go(SB), FARG
    81  	BR	asancall<>(SB)
    82  
    83  // Switches SP to g0 stack and calls (FARG). Arguments already set.
    84  TEXT	asancall<>(SB), NOSPLIT, $0-0
    85  	// LR saved in generated prologue
    86  	// Get info from the current goroutine
    87  	MOVD	runtime·tls_g(SB), R10  // g offset in TLS
    88  	MOVD	0(R10), g
    89  	MOVD	g_m(g), R7		// m for g
    90  	MOVD	R1, R16			// callee-saved, preserved across C call
    91  	MOVD	m_g0(R7), R10		// g0 for m
    92  	CMP	R10, g			// same g0?
    93  	BEQ	call			// already on g0
    94  	MOVD	(g_sched+gobuf_sp)(R10), R1 // switch R1
    95  call:
    96  	// prepare frame for C ABI
    97  	SUB	$32, R1			// create frame for callee saving LR, CR, R2 etc.
    98  	RLDCR	$0, R1, $~15, R1	// align SP to 16 bytes
    99  	MOVD	FARG, CTR		// address of function to be called
   100  	MOVD	R0, 0(R1)		// clear back chain pointer
   101  	BL	(CTR)
   102  	MOVD	$0, R0			// C code can clobber R0 set it back to 0
   103  	MOVD	R16, R1			// restore R1;
   104  	MOVD	runtime·tls_g(SB), R10	// find correct g
   105  	MOVD	0(R10), g
   106  	RET
   107  
   108  // tls_g, g value for each thread in TLS
   109  GLOBL runtime·tls_g+0(SB), TLSBSS+DUPOK, $8
   110
View as plain text